Управление выключателем света любым пультом от бытовой техники

[makaroff]

@Admin
Приветствую! Ну вот и в очередной раз, уже точно, пригодилась Ваша разработка.
Новогодняя ёлочка у меня стоит на шкафу в спальне и очень лень вставать и выключать её перед сном.
Приделал Ваше решение - супер! Включается/выключается - всё замечательно, кроме одного: нужно дистанционное управление минимум ещё одним портом - для перебора режима мигания на контроллере гирлянды.
От того вопрос! Может перекомпилируете под свежую IDE (так как без бубна работает только в 0023) и добавите возможность добавлять несколько кнопок пульта и соответственно несколько портов.
Если лень/некогда, то скажите - буду тогда сам рыть интернеты и курить маны.

Заранее благодарю и с наступающим!

[Admin]

Выложил в теме про Управление рольставнями

[filipow65]

А на две лампы скейч как написать ?

[Admin]

Возьмите за основу скетч от рольставней

[mazaysky]

Доброго времени суток!
У меня небольшая проблема: выключатель программируется и работает, но от ЛЮБОЙ кнопки пульта. Пробовал разные пульты - эффект один.
Возможно ли это от безродного IR приемника, выдранного из китайского псевдо-кондиционера? У него тоже выводы + и вход поменяны местами.
И второе - можно ли Ваш НЕХ залить в Atmega 8?

Заранее спасибо!

[Admin]

Возможно ли это от безродного IR приемника, выдранного из китайского псевдо-кондиционера?

Нет. Скорее всего у пульта очень длинные кодовые посылки

И второе - можно ли Ваш НЕХ залить в Atmega 8?

Нет. Вы можете создать HEX под свой контроллер в Arduino IDE

[Сергей56]

Сообщение от Admin

Вложение 406

Схема выключателя
Вложение 375


Используемые компоненты
Arduino Nano V.7 - 1шт.
Relay Module - 1шт.
ИК приемник TSOP - 1шт. приемник можно использовать любой работающий на частоте 38 кГц
Макетная плата MB-102 - 1шт.

Вложение 374


Видео демонстрирующее работу выключателя


Код для Arduino Nano V.7

PHP код:

#include <IRremote.h>  
#include <avr/delay.h>
#include <EEPROM.h>
#define button 7
#define speaker 11
#define lamp 6

IRrecv irrecv(2);  //вход для ик приемника
decode_results results;  
unsigned long ir_command;
uint8_t swt, count, state = 0;  //статус лампочки
   
void setup()  
{  
  pinMode(speaker, OUTPUT);//громкоговоритель
  pinMode(button, INPUT);//вход для кнопки
  digitalWrite(button,HIGH);//включить подтяжку
  pinMode(lamp, OUTPUT);//лампочка
  irrecv.enableIRIn(); // включить приемник  
}  
   
void loop() 
{  
 swt=digitalRead(button);
 count=0; 
 while(swt==0)
   {
    if(count>30)
     { 
       beep(100,400);
       for(unsigned long i=0; i<2000000; i++)
       {
         if (irrecv.decode(&results))  
          {  
            SaveEEPROM(results.value);  
            irrecv.resume();           
            break;            
          }
        } 
       beep(30,900);  
       break; 
      }
    count++;  
    swt=digitalRead(button);  
    _delay_ms(100); 
   }
  
 ir_command=LoadEEPROM();
    if (irrecv.decode(&results))
    {    
      if(ir_command==results.value) 
        {
          state=~state; 
          digitalWrite(lamp, state);
          beep(10,300); 
          _delay_ms(700); 
        }            
     irrecv.resume();            //очистить входящий буфер 
    } else  if(count>1)        //если было нажатие кнопки выключателя
             { 
               state=~state; //инвертируем статус
               digitalWrite(lamp, state); 
               beep(10,500);
               _delay_ms(100);
             }        
}

void SaveEEPROM(unsigned long ir_code)
{
  EEPROM.write(0, ir_code & 0xFF);
  EEPROM.write(1, (ir_code & 0xFF00) >> 8);
  EEPROM.write(2, (ir_code & 0xFF0000) >> 16);
  EEPROM.write(3, (ir_code & 0xFF000000) >> 24);
}

unsigned long LoadEEPROM() 
{
  byte val = EEPROM.read(3); 
  unsigned long ir_code=val;
      val = EEPROM.read(2);
                ir_code= (ir_code << 8) | val;
      val = EEPROM.read(1);
                ir_code= (ir_code << 8) | val;
      val = EEPROM.read(0);
                ir_code= (ir_code << 8) | val;
  return ir_code;
}

void beep(byte dur, word frq)
{
  dur=(1000/frq)*dur;
  for(byte i=0; i<dur; i++)
  {
   digitalWrite(speaker, HIGH); 
   _delay_us(frq); 
   digitalWrite(speaker, LOW);
   _delay_us(frq);
  } 
} 


Добрый день. Есть два вопроса, можно-ли воспроизвести эту схему на nano 3.0, и пожалуйста опишите по детально прошивку, или ссылку- как это правильно сделать? Пробовал через ED одни ошибки.

[Admin]

можно-ли воспроизвести эту схему на nano 3.0

можно

Пробовал через ED одни ошибки.

что такое ED?

[Сергей56]

Сообщение от Admin

можно

что такое ED?

Извеняюсь ни ED, а IDE Arduino

[Admin]

Библиотеку IRremote.h устанавливали?