Стробоскоп на arduino с регулировкой частоты

[Admin]

Стробоскоп из светодиодной лампы, был сделан для того, что бы показать ребенку как работает камера, телевизор и пр.
В прошлом видео я показывал ему как сделать левитацию воды, при помощи стробоскопа


А теперь собственно о самом стробоскопе:
Стробоскоп собран на arduino nano и из старой, неисправной led лампы.
Частота стробоскопа регулируется энкодером.
При обычном вращении вперед или назад, частота стробоскопа изменяется с шагом 1 Гц.
Если нажать и крутить энкодер, то частота изменяется с шагом 10 Гц.
Начальная частота при включении ардуино 25 Гц.
В скетче все эти параметры можно поменять, они подписаны
Стробоскоп подойдет как для дискотеки, так и для домашних экспериментов.

Схема стробоскопа:


Комплектующие:
Arduino - 1 шт.
Энкодер - 1 шт.
Старая Led лампа -1 шт.
Транзистор КТ972, эмиттер транзистора на GND ардуины. Можно использовать модуль MOSFET
Конденсаторы керамические 0,1 мкФ - 3 шт.

Скетч для ардуино:

PHP код:

// https://duino.ru
#define encoder0PinA 2 // подключен пин А энкодера
#define encoder0PinB 3 // подключен пин В энкодера
#define encoder0Button 4 // подключена кнопка энкодера
#define led_pin 12        // подключен светодиод
#define step_freq 1     // шаг изменения частоты плавно в Гц
#define step_freq_rough 10     // шаг изменения частоты грубо в Гц
#define time_light 2    // время экспозиции или время свечения светодиода в мс
volatile int freq = 25; // частота в Гц

void setup() 
{   
  pinMode(led_pin, OUTPUT);
  pinMode(encoder0PinA, INPUT_PULLUP);
  pinMode(encoder0PinB, INPUT_PULLUP);
  pinMode(encoder0Button, INPUT_PULLUP);
  attachInterrupt(0, EncoderA, FALLING);  // настроить прерывание interrupt 0
  attachInterrupt(1, EncoderB, FALLING);  // настроить прерывание interrupt 1
} 

void loop()
{ 
    digitalWrite(led_pin, 1);
    delay(time_light);                   
    digitalWrite(led_pin, 0);
    if(freq < 1) freq=1; 
    delay(1000/freq-time_light);
}

void EncoderA() // обработка прерывания
{
  if(!digitalRead(encoder0Button) && digitalRead(encoder0PinA)) { freq+=step_freq*step_freq_rough; } //грубая настройка частоты
  else
  if(digitalRead(encoder0PinB)) {freq+=step_freq;}  //плавная настройка частоты
}  

void EncoderB() // обработка прерывания
{
  if(!digitalRead(encoder0Button) && digitalRead(encoder0PinA)) { freq-=step_freq*step_freq_rough; } //грубая настройка частоты
  else
  if( digitalRead(encoder0PinA)) { freq-=step_freq; }   //плавная настройка частоты
} 


Видео тестирования стробоскопа

Не забывайте подписываться на канал

Будут вопросы задавайте в этой теме, в личке спрашивать не нужно.

[Admin]

Изменение кода
Сделал регулировку частоты плавной с шагом 0,1Гц
Так же можно регулировать длительность импулься выдержки, нужно вращать энкодер в нажатом состоянии
Предыдущий код удалять не стал, так как он более понятный для новичков и не посвященных пользователей
Энкодер использует одно прерывание

Схема стробоскопа:


Скетч для ардуино

PHP код:

//Скетч от Cyber-Place.ru

// Выводы ЭНКОДЕРА
#define CLK 3  // Clock Подключаем к INT1, нельзя переназначать
#define DT 4  // второй вывод энкодера
#define SW 5  // switch кнопка энкодера

#define Min 1 // минимальное значение 
#define Max 20000 //максимальное значение
#define led_pin 12        // подключен светодиод
#define coil_pin A0

#define step_freq 1       // шаг изменения частоты плавно 0,1гц
#define step_timelght 100 // шаг приращивания в мкс
volatile int freq = 250; // частота в Гц умноженная на 10, для более плавной настройки
volatile uint32_t paus, time_light=2000; // время свечения светодиода в мкс
uint32_t oldcount;
boolean DT_last; // последнее состояние энкодера

void setup()  
{
  pinMode(CLK,INPUT_PULLUP); // Clock Подключаем к INT1, нельзя переназначать
  pinMode(DT, INPUT_PULLUP); // второй вывод энкодера
  pinMode(SW, INPUT_PULLUP); // кнопка энкодера
  pinMode(led_pin, OUTPUT);    // управление симистором
  pinMode(coil_pin, OUTPUT);

  attachInterrupt(1, encoderTick, CHANGE); // прерывания от Энкодера
  
  DT_last = digitalRead(CLK);         // считываем положение CLK
}

void loop()
{
    paus=5000000/freq;
    digitalWrite(coil_pin, 1);
    digitalWrite(led_pin, 1);
    
    oldcount = micros();
    while( (micros() - oldcount) < time_light){}   // длительность импульса выдержки          
    digitalWrite(led_pin, 0);
    while( (micros() - oldcount) < paus){}  // положительный полупериод
    digitalWrite(coil_pin, 0);
    
    oldcount = micros();
    while( (micros() - oldcount) < paus){} //отрицательный полупериод
}

//********************обработчики прерываний Энкодера*******************************
void encoderTick()     // Обратка прерываний от Энкодера
{
  uint8_t DT_now = digitalRead(CLK);       // считываем текущее положение CLK
  
  if (DT_now != DT_last && digitalRead(SW))   // если предыдущее и текущее положение не равны, значит был поворот 
  {                     
    if (digitalRead(DT) != DT_now)    // если DT не равен CLK, значит вращение по часовой стрелке
    {                             
      if( freq < Max ) freq += step_freq;    // прибавить 
    } else {                                   // если DT равен CLK, значит вращение против часовой
             if( freq > Min ) freq -= step_freq;  // убавить            
            }
  } else 
          if (DT_now != DT_last && !digitalRead(SW)) //если нажата кнопка и было вращение
          {
           if (digitalRead(DT) != DT_now)         // если DT не равен CLK, значит вращение по часовой стрелке
            {                             
              if( time_light < paus ) { time_light += step_timelght; } // убавить длительность           
            } else  if( time_light > 0 ) time_light -= step_timelght;    // прибавить длительность импульса выдержки/
          }
          
  DT_last = DT_now;                   // сохранить положение CLK для следующей проверки
} 


[Tohin]

Решил на входных собрать ребенку игрушку. Не понял зачем нужна переменная
void loop()
{ stat_int=0;

На нее компилятор ругается, в коде вроде не используется, удалил нафик. Вроде работает.
Энкодера у меня не нашлось - заменил на две тактовые кнопки и один выключатель, мне показалось должно работать также.
Но подобрать частоту к каплям из крана у меня не получилось. Но все равно очень прикольно - спасибо!

[Admin]

void loop()
{ stat_int=0;

Не нужна, удали ее. Я не помню для чего она, что то для отладки делал

Энкодера у меня не нашлось - заменил на две тактовые кнопки и один выключатель, мне показалось должно работать также.

Кнопками не удобно и долго регулировать, энкодер можно выковырять из старой мышки

Но подобрать частоту к каплям из крана у меня не получилось. Но все равно очень прикольно - спасибо!

Капли должны очень быстро капать, почти на грани срыва в поток. Можно параллельно светодиодам, подключить электромагнитный клапан или соленоид. И соленоидом дергать трубку или кран, по которой будет течь вода.

[Admin]

Как можно прочитать надпись на вращающемся вентиляторе?
Смотрите на видео

[Maharadon]

Добрый день! Вдохновило, решил сам попробовать собрать, хоть никогда ардуино не занимался и вообще имею посредственные знания по схемоте. Пробовал собрать как на схеме - не работает, подозреваю, что неправильно втыкаю энкодер. На нем обозначения выводов CLK, DT, SW, +, GND. Можете уточнить на Вашей схеме где какой?

[Admin]

#define CLK 3 // Clock Подключаем к INT1, нельзя переназначать
#define DT 4 // второй вывод энкодера
#define SW 5 // switch кнопка энкодера

А стробоскоп моргает?
Скетч лучше использовать второй, а не из шапки

[Maharadon]

А GND и "+" с энкодера сводить на GND ардуины?

Диод не горит. После последней правки начал тлеть, когда случайно тронул ножку диода он загорелся на-полную. Потом тыкался мультиметром и спалил диод. После замены диода схема вновь безжизненна.

[Admin]

А GND и "+" с энкодера сводить на GND ардуины?

Да

Диод не горит. После последней правки начал тлеть, когда случайно тронул ножку диода он загорелся на-полную. Потом тыкался мультиметром и спалил диод. После замены диода схема вновь безжизненна.

Мне сложно , судить не видя полной картины. Возможно что где то ошибка в подключении. При условии что код загружен в контроллер

[sunny]

А GND и "+" с энкодера сводить на GND ардуины?

Если "+"(плюс) подключить к минусу(GND), а вы это похоже делали, то вы получите короткое замыкание (КЗ), с выходом из строя всех критичных к замыканию элементов этой цепи.
По крайней мере если речь идет о питании, а не о линии данных)
Вообщем рисуйте схемы или картинки, чтобы было наглядно и понятно